(defun dialog-import-acad-points (/ DCL_ID LIST-DIALOG-IMPORT-ACAD-POINTS RESULT TEMPLATE)
  ; диалог параметров импортируемого файла и настроек вставки
  
  (setq dcl_id (geo-tools-load-dialog "d_import_acad_points"))
  (setq template
	 (list
	   (list "point" "1")
	   (list "number" "1")
	   (list "elevation" "1")
	   (list "3d" "1")
	   ))
  (if (not(setq list-dialog-import-acad-points (vlax-ldata-get "geo_tools-data-dialogs" "dialog-import-acad-points")))
    (setq list-dialog-import-acad-points template)
    )

  (new_dialog "d_import_acad_points" dcl_id)
  (foreach x list-dialog-import-acad-points
    (set_tile (car x) (cadr x)))

  (action_tile "accept"
    (vl-prin1-to-string
      '(progn
	(foreach x list-dialog-import-acad-points
	 (setq result(append result (list (list (car x)(get_tile (car x))))))
	 )
	(done_dialog 1)
	)))
  (start_dialog)
  (unload_dialog dcl_id)
  (if result(vlax-ldata-put "geo_tools-data-dialogs" "dialog-import-acad-points" result))
  result
  )