(defun get-point-by_numenklature500-msk-saratov (file-name / current-point e-current kol-list n-current num-1 num-2 num-3 num-4 num-kol num-str numenklature-list str-list)
  ; вычисление координат левого нижнего угла планшета по номенклатуре (МСК-Саратов М1:500)
  (setq numenklature-list (convert-string-to-list-be-delimiter file-name "-"))
  (setq num-1 (nth 0 numenklature-list))
  (setq num-2 (nth 1 numenklature-list))
  (setq num-3 (nth 2 numenklature-list))
  (setq num-4 (atoi(nth 3 numenklature-list)))
  
  (setq str-list (list "A" "Б" "В" "Г" "Д" "Е" "Ж" "З" "И" "К" "Л" "М" "Н" "О" "П" "Р"))
  (setq kol-list (list "I" "II" "III" "IV" "V" "VI" "VII" "VIII" "IX" "X" "XI" "XII" "XIII"))
  (if (setq num-str (analysis-number-item-in-list num-1 str-list))
    (setq n-current (- (+ 14000.0 100000.0)(* num-str 2000.0)))); добавил 100000 чтобы небыло минусов
  (if (setq num-kol (analysis-number-item-in-list num-2 kol-list))
    (setq e-current (+ (+ -16000.0 100000.0)(* num-kol 2000.0)))); добавил 100000 чтобы небыло минусов
  
  (if (and n-current e-current)
    (progn
      (setq current-point (list e-current n-current))
      
      (cond
	((= num-3 "а")
	 (setq current-point (mapcar '+ current-point (list 0.0 1000.0)))
	 )
	((= num-3 "б")
	 (setq current-point (mapcar '+ current-point (list 1000.0 1000.0)))
	 )
	((= num-3 "г")
	 (setq current-point (mapcar '+ current-point (list 1000.0 0.0)))
	 )
	)
      (cond
	((< num-4 5)
	 (setq current-point (mapcar '+ current-point (list (* (- num-4 1) 250.0)750.0 )))
	 )
	((< num-4 9)
	 (setq current-point (mapcar '+ current-point (list (* (- num-4 5) 250.0)500.0 )))
	 )
	((< num-4 13)
	 (setq current-point (mapcar '+ current-point (list (* (- num-4 9) 250.0)250.0 )))
	 )
	(T
	 (setq current-point (mapcar '+ current-point (list (* (- num-4 13) 250.0)0.0 )))
	 )
	)
      
      )
    (princ (strcat "\nПланшет "file-name " не определен."))
    )
  
  (mapcar '- current-point (list 100000.0 100000.0));вернуть минусы
;;;  current-point
  )

;test (get-point-by_numenklature500-msk-saratov "Ж-IX-в-7")
; 0.0 2000.000
; 0.0 2000.000
; 500.000 2500.000

;test (get-point-by_numenklature500-msk-saratov "Ж-IX-б-10")
; 0.0 2000.000
; 1000.000 3000.000
; 1250.000 3250.000

;test (get-point-by_numenklature500-msk-saratov "К-III-г-1")

; -12000.000 -4000.000
; -11000.000 -4000.000
; -11000.000 -3500.000