(defun convert-xy-to-bl-wgs-84-by-property (list-property point /
					    a-krassovski a-wgs-84 b-krassovski b-wgs-84 dx dy dz l0
					    list-bl-sk-42 list-bl-wgs-84 list-datum list-sk list-xyz-sk-42 list-xyz-wgs-84
					    m wx wy wz x y)
  (setq list-sk  (cdr (nth 0 list-property)))
  (setq list-datum (cdr (nth 1 list-property)))
  (setq a-wgs-84 6378137.000)
  (setq b-wgs-84 6356752.314)
  (setq a-krassovski 6378245.000)
  (setq b-krassovski 6356863.019)
  (setq
    x (-(nth 1 point) (atof(cdr(assoc "FalseNorthing" list-sk))))
    y (-(nth 0 point) (atof(cdr(assoc "FalseEasting" list-sk))))
    L0 (convert-grad-rad (convert-str-grad-to-deg-grad(cdr(assoc "CMeridian" list-sk))))
    dx (atof(cdr(assoc "DX" list-datum)))
    dy (atof(cdr(assoc "DY" list-datum)))
    dz (atof(cdr(assoc "DZ" list-datum)))
    wx (convert-grad-rad(/ (atof(cdr(assoc "Rx" list-datum))) 3600.0))
    wy (convert-grad-rad(/ (atof(cdr(assoc "Ry" list-datum))) 3600.0))
    wz (convert-grad-rad(/ (atof(cdr(assoc "Rz" list-datum))) 3600.0))
    m (/(atof(cdr(assoc "scale" list-datum)))1000000.0)
    )
  (setq list-bl-sk-42(calculation-xy-gaus-to-bl x y L0 a-krassovski b-krassovski))
  (setq list-XYZ-sk-42(calculation-XYZ-by-BLH (list (convert-rad-grad(nth 0 list-bl-sk-42)) (convert-rad-grad(nth 1 list-bl-sk-42))) a-krassovski b-krassovski))
  (setq list-XYZ-wgs-84(transform-xyz-be-7-property dx dy dz wx wy wz m (nth 0 list-XYZ-sk-42)(nth 1 list-XYZ-sk-42)(nth 2 list-XYZ-sk-42)))
  (setq list-bl-wgs-84 (calculation-BLH-by-XYZ (list (nth 0 list-XYZ-wgs-84) (nth 1 list-XYZ-wgs-84) (nth 2 list-XYZ-wgs-84)) a-wgs-84 b-wgs-84))
  )